DRIVERS: Backup e Restauração Simplificados no Windows!

Se você já perdeu horas reinstalando drivers após formatar o computador, sabe o quão frustrante pode ser. Mas e se existisse uma maneira rápida e fácil de fazer backup e restaurar todos os seus drivers com apenas alguns cliques?

Por que fazer backup dos seus drivers?

Drivers são os programas que permitem que o Windows se comunique com o hardware do seu computador, como placa de vídeo, impressora, etc. Eles são essenciais para o bom funcionamento do sistema. Ao fazer um backup, você garante que terá todos os drivers à mão caso precise reinstalar o Windows ou trocar de computador.

Primeira solução: comandos no terminal

Abaixo seguem os passos necessários para efetuar o Backup e/ou restauração dos arquivos de maneira manual.

Passo a passo:

Backup dos drivers:
- Abrir o terminal do Windows como administrador.
- Executar o comando: dism /online /export-driver /destination:"location" (substituindo “location” pelo caminho da pasta onde você quer salvar o backup).
- O script irá exportar todos os drivers para a pasta especificada.
Restaurar os drivers:
- Abrir o terminal do Windows como administrador após formatar o computador.
- Executar o comando: pnputil /add-driver "LOCAL*.inf" /subdirs /install (substituindo “local” pelo caminho da pasta onde o backup dos drivers está salvo).
- O script irá reinstalar todos os drivers.

Segunda solução: um script inteligente

Criaremos um arquivo Batch com o Notepad do Windows. Basta, no momento de salvar, marcar as opçoes “Todos os Arquivos *.*” escolhendo um some para seu arquivo acrescido da extensão .bat. Ex.: Script.bat

Como funciona?

O script oferece três opções:

Fazer backup dos drivers: O script utiliza o comando dism /online /export-driver para copiar todos os drivers para uma pasta de sua escolha.
Restaurar o backup dos drivers: Utilizando o comando pnputil /add-driver "LOCAL*.inf" /subdirs /install, o script restaura os drivers a partir da pasta onde você os salvou.
Abrir o tutorial : Caso precise relembrar os passos, o script abre esta página pra voc

Passo a passo:

Abra o Notepad do Windows e cole o script abaixo.
Salve o Arquivo com a extensão BAT.
Execute o script como Administrador.
Escolha a opção desejada.

O código fonte do script:

@echo off
chcp 65001

:: Verifica se o script está sendo executado como administrador
net session >nul 2>&1
if %errorlevel% == 0 (
  echo "Script em execução como administrador."
) else (
  echo "Este script precisa ser executado como administrador."
  pause
  exit /b 1
)

cls

:menu
echo Escolha uma opção:
echo 1 - Fazer backup dos drivers
echo 2 - Restaurar o backup dos drivers
echo 3 - Abrir o tutorial
echo 4 - Sair
set /p opcao="Opção: "

setlocal EnableDelayedExpansion

if "!opcao!" == "1" goto backup
if "!opcao!" == "2" goto restaurar
if "!opcao!" == "3" goto tutorial
if "!opcao!" == "4" goto sair

echo Opção inválida. Tente novamente.
goto menu

:backup
echo "Exportando drivers..."

:: Pergunta ao usuário se ele quer usar o caminho padrão ou inserir um caminho
set /p escolha="Deseja usar o caminho padrão (C:\Backup\Drivers) ou inserir um caminho? (s/n): "

if /i "!escolha!" == "s" (
  set "caminho_backup=C:\Backup\Drivers"
) else (
  set /p caminho_backup="Digite o caminho da pasta de backup: "

  :: Verifica se o caminho digitado é válido
  if not exist "!caminho_backup!" (
    echo "Caminho inválido."

    :: Pergunta se o usuário deseja criar a pasta
    set /p criar_pasta="Deseja criar a pasta '!caminho_backup!'? (s/n): "
    if /i "!criar_pasta!" == "s" (
      mkdir "!caminho_backup!"
    ) else (
      echo "Operação cancelada."
      goto menu
    )
  )
)

dism /online /export-driver /destination:"!caminho_backup!"
if !errorlevel! == 0 (
  echo "Backup concluído com sucesso!"
) else (
  echo "Erro durante o backup."
)
pause
goto menu

:restaurar
echo "Restaurando drivers..."

:: Pergunta ao usuário se ele quer usar o caminho padrão ou inserir um caminho
set /p escolha="Deseja usar o caminho padrão (C:\Backup\Drivers) ou inserir um caminho? (s/n): "

if /i "!escolha!" == "s" (
  set "caminho_backup=C:\Backup\Drivers"
) else (
  set /p caminho_backup="Digite o caminho da pasta de backup: "
)

:: Verifica se a pasta de backup existe
if not exist "!caminho_backup!" (
  echo "Erro: A pasta de backup não existe."
  pause
  goto menu
)

:: Restaura os drivers
pnputil /add-driver "!caminho_backup!\*.inf" /subdirs /install
if !errorlevel! == 0 (
  echo "Restauração concluída com sucesso!"
) else (
  echo "Erro durante a restauração."
)
pause
goto menu

:tutorial
start https://rafaelwms.com.br/2025/02/07/drivers-backup-e-restauracao-simplificados-no-windows/
goto menu

:sair
echo "Obrigado e até logo!"
pause
exit /b 1

endlocal

Deixe um comentário Cancelar resposta